Zombie Hunter GUI

More
1 year 7 months ago - 1 year 7 months ago #10 by TheMorgue
Zombie Hunter GUI was created by TheMorgue
A nice toolbar for hunting zombies.
https://files.fm/f/csjn2qh5
https://files.fm/f/q36wa5tb
alias -l DialogOpen { 
  if ($dialog($1) == $1 ) { /dialog -x $1 }
  else { dialog $iif($dialog($1),-v,-m ) $1- | /dialog -s $1 -1 0 1040 110 }
}
menu channel {
  $iif($dialog(tbl_Zombie),Close,Open) Zombie Toolbar:/DialogOpen tbl_Zombie tbl_Zombie
}
; see if it's the "Active Duck hunt Chan"
on 1:ACTIVE:*: .Dh.Test
alias Dh.Test {
  if ($active isin %Dh.chan) { set %Dh.Achan $active } 
  ;else .echo -a false $active last: $lactive achan: %Dh.Achan
}
dialog -l tbl_Zombie {
  title "Zombie Toolbar"
  size -1 0 520 51
  option dbu
  button "Bullet", 1, 44 3 37 10
  button "Clip", 2, 2 27 37 10
  button "AP", 3, 138 2 37 10
  button "Explosive", 4, 94 3 37 10
  button "Repurchase", 5, 44 15 37 10
  button "Grease", 6, 94 27 37 10
  button "Sight", 7, 94 15 37 10
  button "Infa dect", 8, 1 41 37 10
  button "Silencer ", 9, 138 15 37 10
  button "4 leaf clover", 10, 138 27 37 10
  button "Sunglasses ", 11, 38 41 37 10
  button "Spare clothes", 12, 75 41 37 10
  button "Brush for gun", 13, 112 41 37 10
  button "Mirror ", 14, 150 41 37 10
  button "Sand", 15, 187 41 37 10
  button "Water Bucket ", 16, 224 41 37 10
  button "Sabotage ", 17, 261 41 37 10
  button "Life ins", 18, 297 41 37 10
  button "Liability ins", 19, 334 41 37 10
  button "Scarecrow ", 20, 371 41 37 10
  button "Piece of flesh", 21, 407 41 37 10
  button "Zombie dect", 22, 444 41 37 10
  button "Mech zombie", 23, 481 41 37 10
  button "Stats", 24, 214 27 25 9, flat
  button "Stats sNick", 25, 248 27 37 9, flat
  button "Top 10", 26, 181 27 25 9, flat
  box "Description", 44, 179 0 341 26
  edit "", 32, 182 7 334 16, read multi
  button "Shoot", 28, 2 3 37 10
  button "Reload", 29, 2 15 37 10
  text "SelNick", 30, 290 28 74 8, result
  check "Basic", 27, 44 28 50 10
  link "XP", 33, 481 29 12 8
  link "Shop", 34, 497 29 17 8
}
; update selected nick on mouseover dialog
alias -l ZH_Snicks {
  did -ra tbl_Zombie 30 $snick(%Dh.Achan,1)
}
alias -l tbl_Resize {
  if ($did(27).state == 0) { /dialog -s tbl_Zombie -1 0 1040 110 }
  if ($did(27).state == 1) { /dialog -s tbl_Zombie -1 0 170 80 }
}
on *:dialog:tbl_Zombie:sclick:1-13,18-23:{ /msg %Dh.Achan !shop $did }
on *:dialog:tbl_Zombie:sclick:14-17:{ /msg %Dh.Achan !shop $did $snick(%Dh.Achan,1) }
on *:dialog:tbl_Zombie:sclick:24:{ /msg %Dh.Achan !zombiestats }
on *:dialog:tbl_Zombie:sclick:25:{ /msg %Dh.Achan !zombiestats $snick(%Dh.Achan,1) }
on *:dialog:tbl_Zombie:sclick:26:{ /msg %Dh.Achan !zhtop10 }
on *:dialog:tbl_Zombie:sclick:27:{ .tbl_Resize } 
on *:dialog:tbl_Zombie:sclick:28:{ 
  if (#Batcave-Chat == %Dh.Achan ) /msg %Dh.Achan !bang
  else /msg %Dh.Achan !shoot
}
on *:dialog:tbl_Zombie:sclick:29:{ /msg %Dh.Achan !reload }
on *:dialog:tbl_Zombie:sclick:33:{ .run http://hunt.abandoned-irc.net/hunt/xp.html }
on *:dialog:tbl_Zombie:sclick:34:{ .run http://hunt.abandoned-irc.net/hunt/shop.html }
ON *:DIALOG:tbl_Zombie:*:*: {  
  if (( $did > 0 ) && ( $did < 30 )) { did -ra tbl_Zombie 32 $did($did).text $+ : $+ $read($scriptdirZombieShop.txt,n,$did) }
  if ( $did(30).text != $snick(%Dh.Achan,1) ) { did -ra tbl_Zombie 30 $snick(%Dh.Achan,1) }
}
This file shows the tooltips
$mircdirZombieShop.txt
1: One bullet is added directly in the gun chamber. 	7xp
2: One clip is added to your stock. 	20xp
3: Ammo-antiblindage- 	Damage x2 for 24h. Helps killing Super Zombies. 	15xp
4: Damage x3 for 24h. Helps killing Super Zombies. 	25xp
5: Allows you to get your gun back without having to wait. 	40xp
6: Reduces the odds of jaming by 50% for 24h and protects from sand once. 	8xp
7: Improves accuracy for the next shot by -(100 - current accuracy- / 3. 	6xp
8: Locks the trigger when there is no Zombie on sight, thus helping you to save bullets. Works for 24h, blocks 6 times. 	15xp
9: Muffles most of the noise from your gun for 24h so Zombies don't get frightened and escape. 	5xp
10: Win a random XP bonus for each Zombie you shoot for 24h. Bonus can be from 1 to 10 and is determined at purchase. 	13xp
11: Protects from mirror induced glares for 24h. 	5xp
12: Dry set of clothes. Useful when someone poured a bucket of water on you. 	7xp
13: Cancels the sabotage and removes sand from your gun. 	7xp
14: Dazzles another player of your choice and make him lose 50% of his accuracy for his next shot. 	7xp
15: Throw sand on the gun of another player of your choice, his jamming odds will increase by 50% for the next shot. Cancels effects from the grease. 	7xp
16: Throw a bucket of water on the hunter of your choice, forcing him to wait 1h for his clothes to dry before he can hunt again. 	10xp
17: Sabotage the weapon of another player. His weapon will jam and explode at his face the next time he press the trigger. 	14xp
18: Single use insurance policy allowing you to gain a bonus worth 2x the hunter level if you are the victim of a hunting accident for one week. 	10xp
19: Divides the XP penality for hunting accidents by 3 for two days. 	5xp
20: Attracts a zombie in the next 10 minutes. 	8xp
21: Throw pieces of flesh to improve the probability of seeing Zombies for 1h. flesh also makes Zombies stay 20 seconds longer. Multiple pieces of flesh can be bought to cumulate the effects. 	2xp
22: Single use device allowing a hunter to be warned by a notice when the next zombie shows. 	5xp
23: Make a prank to other hunters by launching a fake zombie. They will not gain any XP from it and lose their ammo. The zombie will be automatically launched 10 minutes after you buy it. 	50xp
Show your stats.
Show stats for the name highlighted.
Show the top 10 Zombie hunters. 
Toggle !Shop options Show/Hide Advanced options
Fire all your guns at once baby.
Use ammo from a clip Or to unjam you gun
Last edit: 1 year 7 months ago by TheMorgue. Reason: i forgot the tooltips file
The following user(s) said Thank You: xXBERTOXx

Please Log in or Create an account to join the conversation.

Time to create page: 0.259 seconds
Powered by Kunena Forum